nbxplorer: init at 2.5.26

Backport of https://github.com/NixOS/nixpkgs/pull/407336
Fixes https://github.com/MetacoSA/NBitcoin/pull/1269

pkgs/default.nix

@@ -16,6 +16,7 @@ let self = {
   joinmarket = pkgs.callPackage ./joinmarket { inherit (self) nbPython3PackagesJoinmarket; };
   lndinit = pkgs.callPackage ./lndinit { };
   liquid-swap = pkgs.python3Packages.callPackage ./liquid-swap { };
+  nbxplorer = pkgs.callPackage ./nbxplorer { };
   rtl = pkgs.callPackage ./rtl { inherit (self) fetchNodeModules; };
   inherit (pkgs.callPackage ./mempool { inherit (self) fetchNodeModules; })
     mempool-backend

pkgs/nbxplorer/default.nix

@@ -0,0 +1,40 @@
+{
+  lib,
+  buildDotnetModule,
+  fetchFromGitHub,
+  dotnetCorePackages,
+}:
+
+buildDotnetModule rec {
+  pname = "nbxplorer";
+  version = "2.5.26";
+
+  src = fetchFromGitHub {
+    owner = "dgarage";
+    repo = "NBXplorer";
+    tag = "v${version}";
+    hash = "sha256-gXLzUgFZxrDNbDjpPmVDIj2xi6I+IfkNwXBYvelRYPU=";
+  };
+
+  projectFile = "NBXplorer/NBXplorer.csproj";
+  nugetDeps = ./deps.json;
+
+  dotnet-sdk = dotnetCorePackages.sdk_8_0;
+  dotnet-runtime = dotnetCorePackages.aspnetcore_8_0;
+
+  # macOS has a case-insensitive filesystem, so these two can be the same file
+  postFixup = ''
+    mv $out/bin/{NBXplorer,nbxplorer} || :
+  '';
+
+  meta = with lib; {
+    description = "Minimalist UTXO tracker for HD Cryptocurrency Wallets";
+    maintainers = with maintainers; [
+      kcalvinalvin
+      erikarvstedt
+    ];
+    license = licenses.mit;
+    platforms = platforms.linux ++ platforms.darwin;
+    mainProgram = "nbxplorer";
+  };
+}

pkgs/pinned.nix

@@ -19,8 +19,7 @@ pkgs: pkgsUnstable:
     electrs
     elementsd
     fulcrum
-    lnd
-    nbxplorer;
+    lnd;
 
   inherit pkgs pkgsUnstable;
 }