joinmarket: 0.9.2 -> 0.9.3

pkgs/python-packages/default.nix

@@ -30,6 +30,15 @@ in {
   # twisted 20.3.0, required by joinmarketbase
   twisted = callPackage ./specific-versions/twisted.nix {};
 
+  # autobahn 20.12.3, required by joinmarketclient
+  autobahn = callPackage ./specific-versions/autobahn.nix {};
+
+  # klein 20.6.0, required by joinmarketclient
+  klein = callPackage ./specific-versions/klein.nix {};
+
+  # tubes 0.2.0, required by klein
+  tubes = callPackage ./specific-versions/tubes.nix {};
+
   # recommonmark 0.7.1, required by pyln-client
   recommonmark = callPackage ./specific-versions/recommonmark.nix { inherit (super) recommonmark; };
 }

pkgs/python-packages/jmclient/default.nix

@@ -1,4 +1,4 @@
-{ version, src, lib, buildPythonPackage, fetchurl, future, configparser, joinmarketbase, joinmarketdaemon, mnemonic, argon2_cffi, bencoderpyx, pyaes, joinmarketbitcoin, txtorcon }:
+{ version, src, lib, buildPythonPackage, fetchurl, future, configparser, joinmarketbase, joinmarketdaemon, mnemonic, argon2_cffi, bencoderpyx, pyaes, joinmarketbitcoin, txtorcon, klein, pyjwt, autobahn, cryptography }:
 
 buildPythonPackage rec {
   pname = "joinmarketclient";
@@ -9,7 +9,7 @@ buildPythonPackage rec {
   checkInputs = [ joinmarketbitcoin joinmarketdaemon txtorcon ];
 
   # configparser may need to be compiled with python_version<"3.2"
-  propagatedBuildInputs = [ future configparser joinmarketbase mnemonic argon2_cffi bencoderpyx pyaes ];
+  propagatedBuildInputs = [ future configparser joinmarketbase mnemonic argon2_cffi bencoderpyx pyaes klein pyjwt autobahn cryptography ];
 
   meta = with lib; {
     description = "Client library for Bitcoin coinjoins";

pkgs/python-packages/specific-versions/autobahn.nix

@@ -0,0 +1,36 @@
+# Like nixpkgs revision 8d668463b0883b2e21ba2e2635cd5f9bbc409b18
+# but without Python 2 support
+
+{ lib, buildPythonPackage, fetchPypi,
+  six, txaio, twisted, zope_interface, cffi,
+  mock, pytest, cryptography, pynacl
+}:
+buildPythonPackage rec {
+  pname = "autobahn";
+  version = "20.12.3";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "15b8zm7jalwisfwc08szxy3bh2bnn0hd41dbsnswi0lqwbh962j1";
+  };
+
+  propagatedBuildInputs = [ six txaio twisted zope_interface cffi cryptography pynacl ];
+
+  checkInputs = [ mock pytest ];
+  checkPhase = ''
+    runHook preCheck
+    USE_TWISTED=true py.test $out
+    runHook postCheck
+  '';
+
+  # Tests do no seem to be compatible yet with pytest 5.1
+  # https://github.com/crossbario/autobahn-python/issues/1235
+  doCheck = false;
+
+  meta = with lib; {
+    description = "WebSocket and WAMP in Python for Twisted and asyncio.";
+    homepage    = "https://crossbar.io/autobahn";
+    license     = licenses.mit;
+    maintainers = with maintainers; [ nand0p ];
+  };
+}

pkgs/python-packages/specific-versions/klein.nix

@@ -0,0 +1,29 @@
+{ lib, buildPythonPackage, fetchPypi, python
+, attrs, enum34, hyperlink, incremental, six, twisted, typing, tubes, werkzeug, zope_interface
+, hypothesis, treq
+}:
+
+buildPythonPackage rec {
+  pname = "klein";
+  version = "20.6.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-ZYS5zf9JWbnc7pWhwcIAEPUhoqEsT/PN2LkDqbDpk/Y=";
+  };
+
+  propagatedBuildInputs = [ attrs enum34 hyperlink incremental six twisted typing tubes werkzeug zope_interface ];
+
+  checkInputs = [ hypothesis treq ];
+
+  checkPhase = ''
+    ${python.interpreter} -m twisted.trial -j $NIX_BUILD_CORES klein
+  '';
+
+  meta = with lib; {
+    description = "Klein Web Micro-Framework";
+    homepage    = "https://github.com/twisted/klein";
+    license     = licenses.mit;
+    maintainers = with maintainers; [ exarkun ];
+  };
+}

pkgs/python-packages/specific-versions/tubes.nix

@@ -0,0 +1,29 @@
+{ lib, buildPythonPackage, fetchPypi, python
+, characteristic, six, twisted
+}:
+
+buildPythonPackage rec {
+  pname = "tubes";
+  version = "0.2.0";
+
+  src = fetchPypi {
+    pname = "Tubes";
+    inherit version;
+    sha256 = "0sg1gg2002h1xsgxigznr1zk1skwmhss72dzk6iysb9k9kdgymcd";
+  };
+
+  propagatedBuildInputs = [ characteristic six twisted ];
+
+  checkPhase = ''
+    ${python.interpreter} -m twisted.trial -j $NIX_BUILD_CORES tubes
+  '';
+
+  pythonImportsCheck = [ "tubes" ];
+
+  meta = with lib; {
+    description = "a data-processing and flow-control engine for event-driven programs";
+    homepage    = "https://github.com/twisted/tubes";
+    license     = licenses.mit;
+    maintainers = with maintainers; [ exarkun ];
+  };
+}