webapp/flake.nix

{
  description = "AIO webapp — modular Vue 3 + Vite shell with Lightning + Nostr standalones";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    let
      apps = [ "main" "events" "wallet" "chat" "market" "forum" "tasks" "restaurant" "libra" ];

      # Use this flake's pinned nixpkgs for the build, regardless of which
      # nixpkgs the consumer's `pkgs` is from. Without this, the pnpmDeps
      # hash drifts as soon as a consumer's nixpkgs has a different
      # pnpm_10 minor version (snapshots are byte-for-byte different per
      # pnpm version). Only `pkgs`'s system attribute is honored.
      flakePkgsFor = pkgs: import nixpkgs {
        inherit (pkgs.stdenv.hostPlatform) system;
      };

      mkWebapp = { pkgs, brandDir ? ./branding/default, app ? "main", extraEnv ? {} }:
        let
          buildScript = if app == "main" then "build" else "build:${app}";
          outDir = if app == "main" then "dist" else "dist-${app}";
          flakePkgs = flakePkgsFor pkgs;
        in
        flakePkgs.stdenv.mkDerivation (finalAttrs: {
          pname = "aio-webapp-${app}";
          version = "0.0.0";

          src = ./.;

          # pnpm comes from THIS flake's pinned nixpkgs (via flakePkgs),
          # never the consumer's, so the pnpmDeps snapshot is stable.
          pnpm = flakePkgs.pnpm_10;

          pnpmDeps = flakePkgs.fetchPnpmDeps {
            inherit (finalAttrs) pname version src;
            inherit (finalAttrs) pnpm;
            fetcherVersion = 3;
            hash = "sha256-2azTpxT+zZqNYNbwC7mj187Tn68p4T0626NotPDGuSU=";
          };

          nativeBuildInputs = [
            flakePkgs.nodejs
            finalAttrs.pnpm
            flakePkgs.pnpmConfigHook
            flakePkgs.autoPatchelfHook
          ];

          # sharp's prebuilt libvips binaries (under @img/sharp-libvips-*)
          # are dynamically linked; autoPatchelfHook needs the runtime libs.
          buildInputs = [
            flakePkgs.stdenv.cc.cc.lib
          ];

          # Brand kit env knobs read by vite-branding.ts and
          # pwa-assets.config.ts. brandDir is either ./branding/default
          # (a path inside this flake's source) or an external path that
          # nix has copied into the build sandbox.
          #
          # `extraEnv` flows in VITE_* and any other build-time env vars
          # the caller wants to bake into the bundle (e.g. webapp-module
          # passes VITE_NOSTR_RELAYS / VITE_LNBITS_BASE_URL / …; the
          # server-deploy standalones module passes VITE_BASE_PATH +
          # VITE_APP_NAME for per-app path mounts).
          env = {
            BRAND_DIR = "${brandDir}";
            BRAND_APP = if app == "main" then "" else app;
            # Avoid pnpm 10's interactive modules-purge prompt in the
            # sandbox (ERR_PNPM_ABORTED_REMOVE_MODULES_DIR_NO_TTY).
            CI = "true";
          } // extraEnv;

          buildPhase = ''
            runHook preBuild
            pnpm run ${buildScript}
            runHook postBuild
          '';

          installPhase = ''
            runHook preInstall
            mkdir -p $out
            cp -r ${outDir} $out/
            runHook postInstall
          '';

          meta = with flakePkgs.lib; {
            description = "AIO webapp${if app == "main" then "" else " (${app} standalone)"}";
            homepage = "https://git.atitlan.io/aiolabs/webapp";
            license = licenses.mit;
            platforms = platforms.linux;
          };
        });
    in
    {
      # System-agnostic builder. Downstream NixOS hosts call this from
      # their services/webapp.nix with their own brandDir.
      lib.mkWebapp = mkWebapp;
    }
    // flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; };
        # One package per standalone, all using the aiolabs default brand.
        # `nix build .#<app>` exercises the builder for sanity / CI.
        appPackages = pkgs.lib.genAttrs apps (app: mkWebapp { inherit pkgs app; });
      in
      {
        packages = appPackages // {
          default = appPackages.main;
        };
      });
}